#!/usr/bin/perl -ws
use strict;

our ($h, $help, $ijk, $b, $r, $cm); # Опции

if ($h or $help) {
  print <<HELP;
Переориентирует xyz-файл(ы), зануляя 6 x,y,z-координат у выбранных атомов.
Usage: $0 [-ijk=i,j,k [-b] [-r=l,m,n,...] -cm] file.xyz [> reoriented_file.xyz]
Зависимости: Perl

После опции -ijk нужно перечислить через запятую три номера атомов, 
координаты которых следует занулить. Зануляются следующие координаты:
      x     y     z
 i:  0.00  0.00  0.00    Атом i в центре координат
 j:        0.00  0.00    Атом j на оси x
 k:              0.00    Атом k в плоскости xy
Отрицательный номер - с конца.
Если опция -ijk отсутствует, то предполагается -ijk=1,2,3.

Опция -b означает, что тройка i,j,k будет передвинута в начало.
С опцией -r у перечисленных после нее атомов после переориентации 
поменяется на противоположную координата z. (Для обращения заместителя)
С опцией -cm структуры будут передвинуты в их центры масс
HELP
  exit(0);
}

# Массы изотопов
our %massa = qw(
H  1.007947    He 4.0026022   Li 6.9412      Be 9.0121823   B  10.8117
C  12.01078    N  14.00672    O  15.99943    F  18.99840325 Ne 20.17976
Na 22.9897702  Mg 24.30506    Al 26.9815382  Si 28.08553    P  30.9737612
S  32.0655     Cl 35.4532     Ar 39.9481     K  39.09831    Ca 40.0784
Sc 44.9559108  Ti 47.8671     V  50.94151    Cr 51.99616    Mn 54.9380499
Fe 55.8452     Co 58.9332009  Ni 58.69342    Cu 63.5463     Zn 65.4094
Ga 69.7231     Ge 72.641      As 74.921602   Se 78.963      Br 79.9041
Kr 83.7982     Rb 85.46783    Sr 87.621      Y  88.905852   Zr 91.2242
Nb 92.906382   Mo 95.942      Ru 101.072     Rh 102.905502  Pd 106.421
Ag 107.86822   Cd 112.4118    In 114.8183    Sn 118.7107    Sb 121.7601
Te 127.603     I  126.904473  Xe 131.2936    Cs 132.905452  Ba 137.3277
La 138.90552   Ce 140.1161    Pr 140.907652  Nd 144.243     Sm 150.363
Eu 151.9641    Gd 157.253     Tb 158.925342  Dy 162.5001    Ho 164.930322
Er 167.2593    Tm 168.934212  Yb 173.043     Lu 174.9671    Hf 178.492
Ta 180.94791   W  183.841     Re 186.2071    Os 190.233     Ir 192.2173
Pt 195.0782    Au 196.966552  Hg 200.592     Tl 204.38332   Pb 207.21
Bi 208.980382  Th 232.03811   Pa 231.035882  U  238.028913
);

my ($i,$j,$k) = (1,2,3);
if ($ijk) {
  $ijk=~/(-?\d+),(-?\d+),(-?\d+)/ ?
  ($i,$j,$k) = ($1,$2,$3) :
  die "Номера после -ijk должны быть целыми числами!\n";
  
  die "Номера после -ijk не должны быть нулевыми!\n" if $i==0 or $j==0 or $k==0;
  die "Номера после -ijk не должны быть одинаковыми!\n" if $i==$j or $j==$k or $k==$i;
}

my @r;
if ($r) {
  $r =~ s/^\s+//;      # Убираем пробелы в начале
  $r =~ s/\s+$//;      # Убираем пробелы в конце
  $r =~ s/[\s,]+/,/g;  # Заменяем пробелы на запятые

  unless ($r =~ /^(\d+(-\d+)?,)*\d+(-\d+)?$/g) {
    die "Not valid atom numbers after -r=\n";
  }
  foreach (split /,/, $r) {
    if (/(\d+)-(\d+)/) { # Раскрываем интервалы (i-n)
		  my @a = $1<=$2 ? $1..$2 : reverse $2..$1;
		  push @r, @a;
	  }
    else {push @r, $_}
  } 
}


my $count;
foreach my $mol (read_molden()) {
  $count++;
  my ($ii,$jj,$kk) = ($i,$j,$k);
  my $N = $#$mol;
  foreach ($ii,$jj,$kk) {
    $_ += $N+1 if $_ < 0;
  }
  if ($ii>$N or $jj>$N or $kk>$N) {
    warn "Номер после -ijk больше числа атомов!\n";
    next;
  }
  if (colinearity($mol,$ii,$jj,$kk)) {
    warn "Atoms $ii,$jj,$kk lie on a single line in mol #$count\n";
    next;
  }
  re_orientation($mol,$ii,$jj,$kk);
  
  foreach (@r) {
    if ($_>$N) {
      warn "Номер $_ после -r больше числа атомов!\n";
      next;
    }
    $mol->[$_][3] *= -1;
  }  
  
  if ($b && $ijk) {
    my @ijk;
    my $en = shift @$mol;
    push(@ijk, splice @$mol, $_-1, 1, '') for ($ii,$jj,$kk);
    @$mol = grep {$_} @$mol;
    unshift @$mol, $en, @ijk;
  }
  to_centre_mass($mol) if $cm;
  write_molden($mol);
}

# Читает xyz. Параметры - имена xyz-файлов. Если параметров нет, то <>.
# Возвращает массив найденных молекул.
sub read_molden {
  local @ARGV = @_ ? @_ : @ARGV;
  my $num = qr/-?\d+(?:\.\d+)?/;
  my @mols;
  my $line;
  LOOP:
  while ($line || defined($line = <>)) {
    #print $line;
    if ($line =~/^\s*(\d+)\s*$/) {
      my @mol;
      my $N = $1;
      last LOOP if eof();
      next LOOP if eof(ARGV);
      # Second line
      $line = <>;
      $mol[0]{Comment} = $line;
      chomp $mol[0]{Comment};
      #if ($line =~ /\s($num)\s/o) {
        #$mol[0]{Energy} = $1;
      #}
      #if ($line =~ /Symmetry\s+(\w+)/) {
        #$mol[0]{Symmetry} = $1;
      #}
      ##($mol[0]) = $line =~ /($num)/o;
      for (my $i=1; $i<=$N; $i++) {
        last LOOP if eof();
        next LOOP if eof(ARGV);
        $line = <>;
        #print $line;
        if ($line =~ /^\s*([A-Za-z]{1,2})\s+($num)\s+($num)\s+($num)\s*(.*)/io) {
          $mol[$i] = [$1,$2,$3,$4,$5];
          $mol[$i][0] = ucfirst(lc $mol[$i][0]);
          $mol[$i][0] = 'XX' if $mol[$i][0] eq 'Xx';
        } else {
          next LOOP;
        }
      }
      push @mols, \@mol;
      last LOOP if eof();
    } else {
      undef $line;
    }
  }
  return @mols;
}

# Печатает xyz. Параметры -- список молекул, в конце м.б. имя файла.
# Если последний элемент списка - имя файла (не ссылка на массив),
# то печать в этот файл, иначе - на stdout
sub write_molden {
	my $fh = \*STDOUT;
  if (ref($_[-1]) ne 'ARRAY') {
    my $file = pop @_;
    open $fh, '>', $file or die "Can't write to $file: $!\n";
  }
  
  foreach my $mol (@_) {
		my $N = $#{$mol};
    print $fh " $N\n";
		print $fh $mol->[0]{Comment};
#		print $fh " Energy $mol->[0]{Energy} " if $mol->[0]{Energy};
#		print $fh " Symmetry $mol->[0]{Symmetry} " if $mol->[0]{Symmetry};
		print $fh "\n";
		for (my $i=1; $i<=$N; $i++) {
      my ($atom,$x,$y,$z,$ppm) = @{$mol->[$i]};
      printf $fh " %-2s %12.8f %12.8f %12.8f", $atom, $x, $y, $z;
      printf $fh uc($atom) eq 'H' ? " %10.3f" : " %9.2f"  , $ppm if $ppm;
      print $fh "\n";
		}
	}
  #close $fh;
}

# my ($x,$y,$z) = get_xyz($mol);
# Возвращает список ссылок на массивы 1..$N (@x,@y,@z) молекулы
# (нулевые элементы пустые)
sub get_xyz {
  my $mol = shift;
  my (@x,@y,@z);
  my $N = $#{$mol};
  for (my $i=1; $i<=$N; $i++) {
    $x[$i] = $mol->[$i][1];
    $y[$i] = $mol->[$i][2];
    $z[$i] = $mol->[$i][3];
  }
  return (\@x,\@y,\@z);
}

# put_xyz($mol,\@x,\@y,\@z);
# Помещает координаты из массивов 1..$N (@x,@y,@z) в молекулу
sub put_xyz {
  my ($mol,$x,$y,$z) = @_;
  my $N = $#{$mol};
  return undef if $#{$x} != $N || $#{$y} != $N || $#{$z} != $N;
  for (my $i=1; $i<=$N; $i++) {
    $mol->[$i][1] = $x->[$i];
    $mol->[$i][2] = $y->[$i];
    $mol->[$i][3] = $z->[$i];
  }
  1
}

# centre_to_atom($mol,$i)
# Помещает центр координат молекулы на атом $i
sub centre_to_atom {
  my ($mol,$i) = @_;
	my $N = $#{$mol};
  return undef if $i > $N;
	my ($xi,$yi,$zi) = ($mol->[$i][1],$mol->[$i][2],$mol->[$i][3]);
	for (my $n=1; $n<=$N; $n++) {
	  $mol->[$n][1] -= $xi;
    $mol->[$n][2] -= $yi;
    $mol->[$n][3] -= $zi; 
	}
  1
}

# ($A,$B,$C) = plane_normal($mol,$i,$j,$k);
# Возвращает вектор нормаль к плоскости, проходящей через атомы $i, $j, $k.
# Если атомов больше трех, плоскость через них проводится по наименьшим квадратам.
sub plane_normal {
	my ($mol,@nums) = @_;
  my ($x,$y,$z) = get_xyz($mol);
  my @x = @$x; my @y = @$y; my @z = @$z;
  my ($A,$B,$C);
	return undef if @nums<3;
	if (@nums == 3) {
	  my ($i,$j,$k) = @nums;
		$A = ($y[$j]-$y[$i])*($z[$k]-$z[$i])-($z[$j]-$z[$i])*($y[$k]-$y[$i]);
		$B = ($z[$j]-$z[$i])*($x[$k]-$x[$i])-($x[$j]-$x[$i])*($z[$k]-$z[$i]);
		$C = ($x[$j]-$x[$i])*($y[$k]-$y[$i])-($y[$j]-$y[$i])*($x[$k]-$x[$i]);
		#print "@nums  $A $B $C\n";
	} else {
		my ($X,$Y,$Z,$XX,$YY,$ZZ,$XY,$YZ,$XZ);
		foreach (@nums) {
			$X  += $x[$_];        $Y  += $y[$_];        $Z  += $z[$_];
			$XX += $x[$_]*$x[$_]; $YY += $y[$_]*$y[$_]; $ZZ += $z[$_]*$z[$_];
			$XY += $x[$_]*$y[$_]; $YZ += $y[$_]*$z[$_]; $XZ += $z[$_]*$x[$_];
		}
		# A*XX + B*XY + C*XZ = -X   XX XY XZ | -X 	 -X XY XZ 	XX -X XZ	 XX XY -X
		# A*XY + B*YY + C*YZ = -Y   XY YY YZ | -Y 	 -Y YY YZ 	XY -Y YZ	 XY YY -Y
		# A*XZ + B*YZ + C*ZZ = -Z   XZ YZ ZZ | -Z 	 -Z YZ ZZ 	XZ -Z ZZ	 XZ YZ -Z
		$A = $X*($YZ*$YZ-$YY*$ZZ) + $Y*($XY*$ZZ-$YZ*$XZ) + $Z*($YY*$XZ-$XY*$YZ);
		$B = $X*($XY*$ZZ-$XZ*$YZ) + $Y*($XZ*$XZ-$XX*$ZZ) + $Z*($XX*$YZ-$XY*$XZ);
		$C = $X*($YY*$XZ-$YZ*$XY) + $Y*($YZ*$XX-$XY*$XZ) + $Z*($XY*$XY-$YY*$XX);
	}
  my $normal = sqrt($A**2 + $B**2 +$C**2);
  die "Atoms @nums lie on a single line\n" if $normal==0;
  $A /= $normal; $B /= $normal; $C /= $normal;
	#print "@nums  $A $B $C\n";
	return ($A,$B,$C);
}

# re_orientation($mol,$i,$j,$k);
# Переориентирует молекулу так чтобы у атомов $i,$j,$k были координаты
# $i:  0.00  0.00  0.00
# $j:  f.ff  0.00  0.00
# $k:  f.ff  f.ff  0.00
# Dependecies: plane_normal, colinearity, put_xyz
sub re_orientation {
  my ($mol,$i,$j,$k) = @_;
	centre_to_atom($mol,$i);
	#&write_molden;
  my ($x,$y,$z) = get_xyz($mol);
  my @x = @$x; my @y = @$y; my @z = @$z;
 	
  my $xj = sqrt($x[$j]**2 + $y[$j]**2 + $z[$j]**2);
	my $xk = ($x[$k]*$x[$j] + $y[$k]*$y[$j] + $z[$k]*$z[$j]) / $xj;
	my $yk = sqrt($x[$k]**2 + $y[$k]**2 + $z[$k]**2 - $xk**2);
	my ($A1,$B1,$C1) = plane_normal($mol,$i,$j,$k);
  
	for (my $n=1; $n<=$#{$mol}; $n++) {
	  if ($n != $i && $n != $j && $n != $k) {
			my ($xn,$yn,$zn);
      if (colinearity($mol,$j,$k,$n)) {     # Try colinearity
        my $slope;
        my $xkj = $x[$k]-$x[$j];
        my $ykj = $y[$k]-$y[$j];
        my $zkj = $z[$k]-$z[$j];
        if (abs($xkj)>=abs($ykj) && abs($xkj)>=abs($zkj)) {
          $slope = ($x[$n]-$x[$j])/$xkj;
        }
        elsif (abs($ykj)>=abs($zkj)) {
          $slope = ($y[$n]-$y[$j])/$ykj;
        }
        else {
          $slope = ($z[$n]-$z[$j])/$zkj;
        }
        $zn = 0;
        $yn = $slope*$yk;
        $xn = $slope*($xk-$xj)+$xj;
      }
      else {
        $xn = ($x[$n]*$x[$j] + $y[$n]*$y[$j] + $z[$n]*$z[$j])/$xj;
        $yn = ($x[$n]*$x[$k] + $y[$n]*$y[$k] + $z[$n]*$z[$k] - $xn*$xk) / $yk;
        my $sqr = $x[$n]**2 + $y[$n]**2 + $z[$n]**2 - $xn**2 - $yn**2;
        $sqr = 0 if $sqr < 0;
        $zn = sqrt($sqr);
        my ($A2,$B2,$C2) = plane_normal($mol,$j,$k,$n);
        my $Vec = ($B1*$C2-$C1*$B2)*($x[$k]-$x[$j])+
                  ($C1*$A2-$A1*$C2)*($y[$k]-$y[$j])+
                  ($A1*$B2-$B1*$A2)*($z[$k]-$z[$j]);
        $zn = -$zn if $Vec < 0;
        #print "$Vec\n";
      }
			($x[$n],$y[$n],$z[$n]) =	($xn,$yn,$zn);
		}
	}
	($x[$j],$y[$j],$z[$j],$x[$k],$y[$k],$z[$k]) =	($xj,0,0,$xk,$yk,0);
	put_xyz($mol,\@x,\@y,\@z);
  #&write_molden;
}

sub colinearity {
  my ($mol,$i,$j,$k) = @_;
  my $eps = 1e-6;
  my $rij = sqrt(($mol->[$i][1]-$mol->[$j][1])**2+
                 ($mol->[$i][2]-$mol->[$j][2])**2+
                 ($mol->[$i][3]-$mol->[$j][3])**2);
  my $rik = sqrt(($mol->[$i][1]-$mol->[$k][1])**2+
                 ($mol->[$i][2]-$mol->[$k][2])**2+
                 ($mol->[$i][3]-$mol->[$k][3])**2);
  my $rjk = sqrt(($mol->[$k][1]-$mol->[$j][1])**2+
                 ($mol->[$k][2]-$mol->[$j][2])**2+
                 ($mol->[$k][3]-$mol->[$j][3])**2);
  my ($r1,$r2,$r3) = sort {$a<=>$b} ($rij,$rik,$rjk);
  if ($r1<$eps) {
    warn "Two atoms from $i,$j,$k coincide\n";
    return 1;
  }
  if ($r1+$r2-$r3<$eps) {
    return 1;
  }
  return undef;
}

sub to_centre_mass {
# centre_to_atom($mol)
# Помещает центр координат молекулы в центр масс
  my $mol = shift;
	my $N = $#{$mol};
  #return undef if $i > $N;
	
  my ($x0,$y0,$z0,$M);
  for (my $i=1; $i<=$N; $i++) {
	  my $m = $massa{$mol->[$i][0]};
    $x0 += $m * $mol->[$i][1];
	  $y0 += $m * $mol->[$i][2];
	  $z0 += $m * $mol->[$i][3];
    $M += $m;
	}
  $x0 /= $M; 
  $y0 /= $M; 
  $z0 /= $M; 
  
	for (my $i=1; $i<=$N; $i++) {
	  $mol->[$i][1] -= $x0;
    $mol->[$i][2] -= $y0;
    $mol->[$i][3] -= $z0; 
	}
#	my $rms;
#  for (my $i=1; $i<=$N; $i++) {
#	  $rms += $massa{$mol->[$i][0]}*($mol->[$i][1]**2+$mol->[$i][2]**2+$mol->[$i][3]**2);
#	}
#  return sqrt($rms);
  return 1;
}